;PALASM Design Description
;---------------------------------- Declaration Segment ------------
TITLE    BCD counter in 7 seg display
PATTERN  PAL 1 
REVISION First
AUTHOR   Mike Lhamon
COMPANY  University of Kentucky
DATE     11/21/03

CHIP  Seg7_c  PAL22V10
;---------------------------------- PIN Declarations ---------------
PIN  1 clk
pin  2 /reset

;outputs
pin 14 /a           registered
pin 15 /b           registered
pin 16 /c           registered
pin 17 /d           registered
pin 18 /e           registered
pin 19 /f           registered
pin 20 /g           registered

node   1   global

string zero  ' a * b * c * d * e * f */g'
string one   '/a * b * c */d */e */f */g'
string two   ' a * b */c * d * e */f * g'
string three ' a * b * c * d */e */f * g'
string four  '/a * b * c */d */e * f * g'
string five  ' a */b * c * d */e * f * g'
string six   ' a */b * c * d * e * f * g'
string seven ' a * b * c */d */e * f */g'
string eight ' a * b * c * d * e * f * g'
string nine  ' a * b * c */d */e * f * g'
string clear '/a */b */c */d */e */f */g'

;----------------------------------- Boolean Equation Segment ------
EQUATIONS

; Counts directly in 7-seg. digits.
; Note Equations are not reduced

; identify all digits that are going to be set a(n+1) to logic 1
; and assume zero for all else

a := one + two + four + five + six + seven + eight + nine + clear
b := zero + one + two + three + six + seven + eight + nine + clear
c := zero + two + three + four + five + six + seven + eight + nine + clear
d := one + two + four + five + seven + nine + clear
e := one + five + seven + nine + clear
f := three + four + five + six + seven + eight + nine + clear
g := one + two + three + four + five + seven + eight

global.rstf = /reset

;----------------------------------- Simulation Segment ------------
SIMULATION
trace_on clk a b c d e f g reset
setf   reset
clockf clk
setf   reset
for count := 1 to 20 do
    begin
      clockf clk
    end

trace_off
;-------------------------------------------------------------------